Внимание!
Эта wiki об устаревших версиях
Документация к актуальной версии интеграции 1С и телефонии доступна по ссылке

Инструменты пользователя

Инструменты сайта


astpanel:designer:crm3_0

ИНТЕГРАЦИЯ ПАНЕЛИ ТЕЛЕФОНИИ В CRM 3.0

Обратно, к списку конфигураций...

Инструкция проверена с конфигурациями:
  • 1С:CRM, версии 3.0.9.4;
  • Управление торговлей и взаимоотношениями с клиентами, версии 3.0.8.12;
  • Управление нашей фирмой 1.6.13.60 + CRM 3.0.6.9;
  • 1С:Комплексная автоматизация 2.4.8.92 + Модуль 1C:CRM 3.0.15.7;
  • 1С:ERP Управление предприятием 2.4.9.70 + Модуль 1С:CRM 3.0.15.8.
Требуется панель телефонии версии 1.4.26.31+
Сделайте РЕЗЕРВНУЮ КОПИЮ информационной базы.

Настройка поддержки

Необходимо включить возможность изменения конфигурации.

Порядок действий следующий:

  1. Убедитесь, что все пользователи завершили свою работу с программой.
  2. Сделайте РЕЗЕРВНУЮ КОПИЮ информационной базы.
  3. Запустите программу в режиме «Конфигуратор».
  4. Откройте окно настройки поддержки «Конфигуратор» - «Поддержка» - «Настройка поддержки».
  5. Включите возможность изменения конфигурации. На предупреждение программы ответьте утвердительно.
  6. В появившемся окне укажите, что объекты поставщика редактируются с сохранением поддержки.

Конфигурация готова к внесению изменений.

Создание новых объектов

  1. Вставьте внешнюю обработку, которая идет в поставке, присвойте ей имя «МИКО_ПанельТелефонииДля1С».
  2. Добавьте новый общий модуль «МИКО_Софтфон».
  3. Установите флажки напротив свойств «Сервер» и «Вызов сервера» модуля.
  4. Скопируйте текст, расположенный по данной ссылке, и вставьте его в модуль «МИКО_Софтфон».

Дополнительные объекты для интеграции с подсистемой CRM 3

Для выполнения пункта необходим модуль оптимизации версии 1.19+
  1. Скачайте конфигурацию оптимизации версии 1.19. Конфигурация оптимизации доступна по ссылке, и в дистрибутиве поставки панели телефонии версии 1.4.26.25+
  2. «Конфигурация» - «Сравнить и объеденить с конфигурацией из файла»
  3. Выберите файл конфигурации «opt_v1_19.cf» (дистрибутив панели телефонии, каталог «Оптимизация»)
  4. Снимите флажок со всех объектов конфигурации
  5. Меню «Действия» - «Отметить по подсистемам файла»
  6. Выберите только подсистему «МИКО_ПанельТелефонии_CRM3»
  7. Выполните действие «Установить»
  8. Выполните действие «Выполнить» (сравнение и объединение будет завершено)

Настройка прав доступа

  1. Добавьте в конфигурацию новую роль «МИКО_Софтфон».
  2. Снимите все отметки о правах выставляемые по умолчанию, а для обработки МИКО_ПанельТелефонииДля1СМИКО_ПанельТелефонииДля1С») установите все права.

Изменение глобального модуля

  1. Откройте модуль управляемого приложения.
  2. Перейдите к процедуре «ПриЗавершенииРаботыСистемы» (создайте процедуру, если ее нет). В конец процедуры вставьте код приведенный ниже.
    	// PT1C / Панель телефонии Asterisk / Начало
    	Если сфпПанельУправления <> Неопределено
    		 И ТипЗнч(сфпПанельУправления) = Тип("УправляемаяФорма") 
    		 И Найти(сфпПанельУправления.ИмяФормы,"Обработка.МИКО_ПанельТелефонииДля1С")<>0 Тогда
    		сфпПанельУправления.ЗавершитьРаботу(Истина);
    	КонецЕсли;
    	// PT1C / Панель телефонии Asterisk / Конец

Изменение общих модулей

  1. Передите к общему модулю «сфпСофтФонПроКлиент»,
  2. К процедуре «сфпПодключитьСофтФон». В начало необходимо вставить фрагмент кода:
    	// PT1C / Панель телефонии Asterisk / Начало
    	НазваниеПанелиТелефонии = "Панель телефонии Asterisk (МИКО)";
    	Если сфпПанельУправления = Неопределено Тогда
    		МИКО_Софтфон.ВыполнитьПервичнуюУстановку(НазваниеПанелиТелефонии);
    	КонецЕсли; 
     
    	Если МИКО_Софтфон.Использовать(НазваниеПанелиТелефонии) Тогда
    		Если сфпПанельУправления = Неопределено Тогда
    			Попытка
    				сфпПанельУправления = ПолучитьФорму("Обработка.МИКО_ПанельТелефонииДля1С.Форма.Форма");
    				сфпПанельУправления.ИнициализироватьПанельТелефонии(Истина, Ложь);
    			Исключение
    				Сообщить("Не удалось запустить ""Панель телефонии Asterisk (МИКО)""!");
    				Возврат;
    			КонецПопытки;
    		Иначе
    			// Переопределение обработки команды 
    			Если сфпПанельУправления.Открыта() Тогда
    				сфпПанельУправления.Активизировать(); 
    			Иначе
    				сфпПанельУправления.Открыть();
    			КонецЕсли;
    		КонецЕсли; 
    		Возврат;
    	КонецЕсли;
    	// PT1C / Панель телефонии Asterisk / Конец
  3. К процедуре «сфпПозвонитьВыбравТелефон». В начало необходимо вставить фрагмент кода:
    	// PT1C / Панель телефонии Asterisk / Начало
    	Если МИКО_Софтфон.Использовать("Панель телефонии Asterisk (МИКО)") Тогда
     
    		Если ДанныеЗаполнения <> Неопределено
    			И ДанныеЗаполнения.Свойство("Основание") Тогда
     
    			ОснованиеЗвонка = Новый Структура("ОснованиеЗвонка", ДанныеЗаполнения.Основание);
     
    			Если ДанныеЗаполнения.Свойство("Взаимодействие") Тогда
    				ОснованиеЗвонка.Вставить("Взаимодействие",ДанныеЗаполнения.Взаимодействие);
    			КонецЕсли; 
    		КонецЕсли;
     
    		сфпПанельУправления.ПозвонитьВыбравТелефон(СписокОбъектов,,ОснованиеЗвонка);
    		сфпДанныеЗаполнения = ДанныеЗаполнения;
    		Возврат;	
    	КонецЕсли;
    	// PT1C / Панель телефонии Asterisk / Конец
  4. К процедуре «сфпПроверитьДоступностьСофтФон». В начало необходимо вставить фрагмент кода:
    	// PT1C / Панель телефонии Asterisk / Начало
    	Если МИКО_Софтфон.Использовать("Панель телефонии Asterisk (МИКО)") Тогда
    		Возврат Истина;
    	КонецЕсли;
    	// PT1C / Панель телефонии Asterisk / Конец
  5. К процедуре «сфпПолучитьФайлРазговора». В начало необходимо вставить фрагмент кода:
    	// PT1C / Панель телефонии Asterisk / Начало
    	Если МИКО_Софтфон.Использовать("Панель телефонии Asterisk (МИКО)") Тогда
    		Если сфпПанельУправления<>Неопределено Тогда
    			сфпПанельУправления.ПрослушатьЗвонокПоИдентификатору(ИдентификаторЗаписи);
    		КонецЕсли; 
    		Возврат;	
    	КонецЕсли;
    	// PT1C / Панель телефонии Asterisk / Конец
  6. К функции «сфпПозвонить». В начало необходимо вставить фрагмент кода:
Фрагмент кода предназначен для конфигураций с подсистемой CRM версии 3.0.13.1+. Для более ранних версий используйте код по ссылке.
	// PT1C / Панель телефонии Asterisk / Начало
	Если МИКО_Софтфон.Использовать("Панель телефонии Asterisk (МИКО)") Тогда
		ОснованиеЗвонка = Неопределено;
 
		ДопПараметры = Вычислить("ДопПараметры");
 
		Если ДопПараметры = Неопределено Тогда
 
			ДопПараметры = Вычислить("ДанныеЗаполнения");	
 
		КонецЕсли; 
 
		Если ДопПараметры <> Неопределено
			И ДопПараметры.Свойство("ДанныеЗаполнения") Тогда
 
			ДанныеЗаполнения = ДопПараметры.ДанныеЗаполнения;
		Иначе
			ДанныеЗаполнения = ДопПараметры;
		КонецЕсли;
 
 
		Если ДанныеЗаполнения <> Неопределено
			И ДанныеЗаполнения.Свойство("Основание") Тогда
 
			ОснованиеЗвонка = Новый Структура("ОснованиеЗвонка, НомерТелефона", ДанныеЗаполнения.Основание, Телефон);
 
			Если ДанныеЗаполнения.Свойство("Взаимодействие") Тогда
				ОснованиеЗвонка.Вставить("Взаимодействие",ДанныеЗаполнения.Взаимодействие);
			КонецЕсли; 
		КонецЕсли;
		сфпПанельУправления.Позвонить(Телефон,ОснованиеЗвонка);
		сфпДанныеЗаполнения = ДанныеЗаполнения;
		Возврат Истина;	
	КонецЕсли;
	// PT1C / Панель телефонии Asterisk / Конец

Изменение общих форм

  1. Перейти к общей форме «CRM_СообщенияПодключения». В модуле формы, в процедуре «ПриСозданииНаСервере» необходимо добавить фрагмент кода:
    Процедура ПриСозданииНаСервере(Отказ, СтандартнаяОбработка)
     
    	Если НЕ Параметры.Свойство("ВидФормы") Тогда
    		Отказ = Истина;
     
    	ИначеЕсли Параметры.ВидФормы = "СофтФон" Тогда
    		// PT1C / Панель телефонии Asterisk / Начало
    		Если МИКО_Софтфон.Использовать("Панель телефонии Asterisk (МИКО)") Тогда
    			Возврат;
    		КонецЕсли;
    		// PT1C / Панель телефонии Asterisk / Конец
     
    	// *** *** ***
    	// ВНИМАНИЕ ПРОПУЩЕНА ЧАСТЬ ИСХОДНОГО КОДА
    	// *** *** ***
     
    	КонецЕсли;
    КонецПроцедуры // ПриСозданииНаСервере()
  2. Перейти к общей форме «ПечатьДокументов». В конец процедуры «ПриСозданииНаСервере» необходимо добавить фрагмент кода:
    	// PT1C / Панель телефонии Asterisk / Начало
    	МИКО_Софтфон.ДобавитьКнопкиФаксаНаФормуПечати(ЭтаФорма);
    	// PT1C / Панель телефонии Asterisk / Конец
  3. После процедуры «ПриСозданииНаСервере», добавить дополнительные процедуры - обработки:
    &НаКлиенте
    Процедура МИКО_ОтправитьКакФакс()
    	Если НЕ МИКО_Софтфон.Использовать("Панель телефонии Asterisk (МИКО)") 
    		 ИЛИ сфпПанельУправления = Неопределено Тогда
    	 	Возврат;
    	КонецЕсли;
     
    	ТабличныеДокументы = Новый СписокЗначений;
    	Для Каждого НастройкаПечатнойФормы Из НастройкиПечатныхФорм Цикл
    		Если Элементы[НастройкаПечатнойФормы.ИмяРеквизита].Вывод = ИспользованиеВывода.Разрешить И НастройкаПечатнойФормы.Печатать Тогда
    			ТабличныеДокументы.Добавить(ЭтотОбъект[НастройкаПечатнойФормы.ИмяРеквизита], НастройкаПечатнойФормы.Представление);
    		КонецЕсли;
    	КонецЦикла;
     
    	Если ТабличныеДокументы.Количество()=0 Тогда
    		Возврат;
    	Иначе
    		ТабДок = ТабличныеДокументы[0].Значение;
    	КонецЕсли; 
    	// отсылаем факс
    	сфпПанельУправления.ОтправитьФайлПоФаксу(,ТабДок);	
    КонецПроцедуры // МИКО_ОтправитьКакФакс()
     
    &НаКлиенте 
    Процедура МИКО_Позвонить()
    	Если НЕ МИКО_Софтфон.Использовать("Панель телефонии Asterisk (МИКО)") 
    		 ИЛИ сфпПанельУправления = Неопределено Тогда
    	 	Возврат;
    	КонецЕсли; 
     
    	ПараметрыПечати = Неопределено;
     
    	Если ТипЗнч(ОбъектыПечати) = Тип("СписокЗначений")
    		И ОбъектыПечати.Количество() > 0 Тогда
     
    		Участник = МИКО_Софтфон.ПолучитьСсылкуНаУчастникаИзДокумента(ОбъектыПечати[0].Значение);
    		Если ТипЗнч(Участник) = Тип("Массив") 
    			И Участник.Количество()>0 Тогда
    			сфпПанельУправления.ПозвонитьВыбравТелефон(Участник);
    		ИначеЕсли Участник <> Неопределено Тогда
    			СписокУчастников = Новый Массив(1);
    			СписокУчастников[0] = Участник;
    			сфпПанельУправления.ПозвонитьВыбравТелефон(СписокУчастников);
    		КонецЕсли;
    	КонецЕсли; 
     
    КонецПроцедуры

Добавление картинок

В общие картинки добавить

  1. Картинку с именем «МИКО_ЗаписьРазговора»
  2. Картинку с именем «МИКО_Телефон»
  3. Картинку с именем «МИКО_ОтправитьФакс»

Обратно, к списку конфигураций...

Первый запуск

  1. Необходимо запустить 1С под учетной записью администратора 1С.
  2. Перейдите в раздел «Настройки» → «Настройки системы» → «Интеграция с телефонией(Софтфон)»
  3. Необходимо включить использование СофтФона. Для возможности прослушивания записей разговоров из документа «Телефонный звонок» нужно установить настройку «Система записи переговоров, настроенная на сервере СофтФон»
  4. Перейдите в раздел «Настройки» → АдминистрированиеНастройки пользователей и прав
  5. Перейдите в раздел «Пользователи»
  6. Для текущего пользователя следует перейти в «Персональные настройки».
  7. Включите опции:
  • «Использовать СофтФон»
  • «Панель телефонии Asterisk (МИКО)»
  • «Использовать внутреннюю панель СофтФон»

Как запустить панель телефонии 1С?

Для запуска панели телефонии перейдите в ОрганайзерИнтеграция и запустите ПанельСофтфон

Настройки пользователя в панели для конфигураций CRM 3

Для конфигураций с подсистемой CRM 3 в настройках панели телефонии можно установить параметр «Открывать в начале разговора» - «Согласно персональных настроек CRM»(данная настройка персональная, ее нужно установить у каждого пользователя панели телефонии). При этом будут использоваться стандартные механизмы CRM.

В персональных настройках пользователя CRM можно указать различные действия на входящие и исходящие звонки.

Перейти к инструкции по настройке в режиме предприятия

Коментарии

astpanel/designer/crm3_0.txt · Последние изменения: 2020/02/26 14:18 — imal